comment     =  "(" *(ctext / quoted-pair / comment) ")"
     ctext       =  <any CHAR excluding "(",     ; => may be folded
                     ")", "\" & CR, & including
                     linear-white-space>
     quoted-pair =  "\" CHAR                     ; may quote any char
     linear-white-space =  1*([CRLF] LWSP-char)  ; semantics = SPACE
                                                 ; CRLF => folding
     LWSP-char   =  SPACE / HTAB                 ; semantics = SPACE
     CHAR        =  <any ASCII character>        ; (  0-177,  0.-127.)
     CRLF        =  CR LF
     LF          =  <ASCII LF, linefeed>         ; (     12,      10.)
     CR          =  <ASCII CR, carriage return>  ; (     15,      13.)
     SPACE       =  <ASCII SP, space>            ; (     40,      32.)
     HTAB        =  <ASCII HT, horizontal-tab>   ; (     11,       9.)

If a comment is to be "folded" onto multiple lines, then the syntax for folding must be adhered to. (See the "Lexical Analysis of Messages" section on "Folding Long Header Fields" above, and the section on "Case Independence" below.) Note that the official semantics therefore do not "see" any unquoted CRLFs that are in comments, although particular parsing programs may wish to note their presence. For these programs, it would be reasonable to interpret a "CRLF LWSP-char" as being a CRLF that is part of the comment; i.e., the CRLF is kept and the LWSP-char is discarded. Quoted CRLFs (i.e., a backslash followed by a CR followed by a LF) still must be followed by at least one LWSP-char.

[37] comment が複数行に「折畳まれている」時は、折畳みの構文をくっつけないといけません。 (上の「長い頭領域の折畳み」の「メッセージの単語分析」の節と、下の「大文字・小文字の区別性」の節を参照。) 従って、公式な意味においては comment 中にある quote されていない CRLF を「見る」ことはありません。 但しそうしたものの出現に注意したいと思う解析プログラムもあることでしょう。 そうしたプログラムでは、「CRLF LWSP-char」を CRLF が comment の一部であると 解釈する、つまり CRLF は残して, LWSP-char を棄てるのが適切かもしれません。 Quote された CRLF LWSP-char (すなわち、 逆斜線に CR が続いて、 LF が続くもの) は依然、最低一つの LWSP-char が後に続かなければなりません。

  comment         =       "(" *([FWS] ccontent) [FWS] ")"
  FWS             =       ([*WSP CRLF] 1*WSP) /   ; Folding white space
                          obs-FWS
  ccontent        =       ctext / quoted-pair / comment
  ctext           =       NO-WS-CTL /     ; Non white space controls
                          %d33-39 /       ; The rest of the US-ASCII
                          %d42-91 /       ;  characters not including "(",
                          %d93-126        ;  ")", or "\"
  quoted-pair     =       ("\" text) / obs-qp
  NO-WS-CTL       =       %d1-8 /         ; US-ASCII control characters
                          %d11 /          ;  that do not include the
                          %d12 /          ;  carriage return, line feed,
                          %d14-31 /       ;  and white space characters
                          %d127
  text            =       %d1-9 /         ; Characters excluding CR and LF
                          %d11 /
                          %d12 /
                          %d14-127 /
                          obs-text
  
  obs-FWS         =       1*WSP *(CRLF 1*WSP)
  obs-qp          =       "\" (%d0-127)
  obs-text        =       *LF *CR *(obs-char *LF *CR)
  obs-char        =       %d0-9 / %d11 /          ; %d0-127 except CR and
                          %d12 / %d14-127         ;  LF
  
  ;; RFC 2234
  WSP             =  SP / HTAB    ; white space
  CRLF            =  CR LF        ; Internet standard newline
  SP              =  %x20         ; space
  HTAB            =  %x09         ; horizontal tab
  CR              =  %x0D         ; carriage return
  LF              =  %x0A         ; linefeed