5. DATE AND TIME SPECIFICATION

     date-time   =  [ day "," ] date time        ; dd mm yy
                                                 ;  hh:mm:ss zzz

     day         =  "Mon"  / "Tue" /  "Wed"  / "Thu"
                 /  "Fri"  / "Sat" /  "Sun"

     date        =  1*2DIGIT month 2DIGIT        ; day month year
                                                 ;  e.g. 20 Jun 82

     month       =  "Jan"  /  "Feb" /  "Mar"  /  "Apr"
                 /  "May"  /  "Jun" /  "Jul"  /  "Aug"
                 /  "Sep"  /  "Oct" /  "Nov"  /  "Dec"

     time        =  hour zone                    ; ANSI and Military

     hour        =  2DIGIT ":" 2DIGIT [":" 2DIGIT]
                                                 ; 00:00:00 - 23:59:59

     zone        =  "UT"  / "GMT"                ; Universal Time
                                                 ; North American : UT
                 /  "EST" / "EDT"                ;  Eastern:  - 5/ - 4
                 /  "CST" / "CDT"                ;  Central:  - 6/ - 5
                 /  "MST" / "MDT"                ;  Mountain: - 7/ - 6
                 /  "PST" / "PDT"                ;  Pacific:  - 8/ - 7
                 /  1ALPHA                       ; Military: Z = UT;
                                                 ;  A:-1; (J not used)
                                                 ;  M:-12; N:+1; Y:+12
                 / ( ("+" / "-") 4DIGIT )        ; Local differential
                                                 ;  hours+min. (HHMM)

          If included, day-of-week must be the day implied by the date
     specification.

          Time zone may be indicated in several ways.  "UT" is Univer-
     sal  Time  (formerly called "Greenwich Mean Time"); "GMT" is per-
     mitted as a reference to Universal Time.  The  military  standard
     uses  a  single  character for each zone.  "Z" is Universal Time.
     "A" indicates one hour earlier, and "M" indicates 12  hours  ear-
     lier;  "N"  is  one  hour  later, and "Y" is 12 hours later.  The
     letter "J" is not used.  The other remaining two forms are  taken
     from ANSI standard X3.51-1975.  One allows explicit indication of
     the amount of offset from UT; the other uses  common  3-character
     strings for indicating time zones in North America.

2.1.2. Date

    The "Date" line (formerly "Posted") is the date that the message was
    originally posted to the network.  Its format must be acceptable
    both in RFC-822 and to the getdate(3) routine that is provided with
    the Usenet software.  This date remains unchanged as the message is
    propagated throughout the network.  One format that is acceptable to
    both is:

                      Wdy, DD Mon YY HH:MM:SS TIMEZONE

    Several examples of valid dates appear in the sample message above.
    Note in particular that ctime(3) format:

                          Wdy Mon DD HH:MM:SS YYYY

    is not acceptable because it is not a valid RFC-822 date.  However,
    since older software still generates this format, news
    implementations are encouraged to accept this format and translate
    it into an acceptable format.

    There is no hope of having a complete list of timezones.  Universal
    Time (GMT), the North American timezones (PST, PDT, MST, MDT, CST,
    CDT, EST, EDT) and the +/-hhmm offset specifed in RFC-822 should be
    supported.  It is recommended that times in message headers be
    transmitted in GMT and displayed in the local time zone.

5.2.14 RFC-822 Date and Time Specification: RFC-822 Section 5

         The syntax for the date is hereby changed to:

            date = 1*2DIGIT month 2*4DIGIT

         All mail software SHOULD use 4-digit years in dates, to ease
         the transition to the next century.

         There is a strong trend towards the use of numeric timezone
         indicators, and implementations SHOULD use numeric timezones
         instead of timezone names.  However, all implementations MUST
         accept either notation.  If timezone names are used, they MUST
         be exactly as defined in RFC-822.

         The military time zones are specified incorrectly in RFC-822:
         they count the wrong way from UT (the signs are reversed).  As
         a result, military time zones in RFC-822 headers carry no
         information.

         Finally, note that there is a typo in the definition of "zone"
         in the syntax summary of appendix D; the correct definition
         occurs in Section 3 of RFC-822.

RFC 2822 3.3. Date and Time Specification

Date and time occur in several header fields. This section specifies the syntax for a full date and time specification. Though folding white space is permitted throughout the date-time specification, it is RECOMMENDED that a single space be used in each place that FWS appears (whether it is required or optional); some older implementations may not interpret other occurrences of folding white space correctly.

日付と時刻は幾つかの頭欄に現れます。この節では完全な日付と時刻の記述の構文を規定します。折畳み空白間隔は date-time 記述の至る所で認められていますが、 FWS が出現する各部位では (必須であろうと省略可能であろうと) 1つの間隔を使用することを推奨します。 古い実装は折畳み空白間隔を正しく解釈しないかもしれません。

• date-time = [ day-of-week "," ] date FWS time [CFWS]
• day-of-week = ([FWS] day-name) / obs-day-of-week
• day-name = "Mon" / "Tue" / "Wed" / "Thu" / "Fri" / "Sat" / "Sun"
• date = day month year
• year = 4*DIGIT / obs-year
• month = (FWS month-name FWS) / obs-month
• month-name = "Jan" / "Feb" / "Mar" / "Apr" / "May" / "Jun" / "Jul" / "Aug" / "Sep" / "Oct" / "Nov" / "Dec"
• day = ([FWS] 1*2DIGIT) / obs-day
• time = time-of-day FWS zone
• time-of-day = hour ":" minute [ ":" second ]
• hour = 2DIGIT / obs-hour
• minute = 2DIGIT / obs-minute
• second = 2DIGIT / obs-second
• zone = (( "+" / "-" ) 4DIGIT) / obs-zone

The day is the numeric day of the month. The year is any numeric year 1900 or later.

day (日) は月の中の日を数値で表したものです。 year (年) は1900年以降の数値で表した年です。

The time-of-day specifies the number of hours, minutes, and optionally seconds since midnight of the date indicated.

time-of-day (日の時刻) は時と分、それに省略可能ですが秒を指定します。これは示す日付の真夜中から起算したものです。

The date and time-of-day SHOULD express local time.

date (日付) と time-of-day (日の時刻) は地方時を表現するのが 良いです。

The zone specifies the offset from Coordinated Universal Time (UTC, formerly referred to as "Greenwich Mean Time") that the date and time-of-day represent. The "+" or "-" indicates whether the time-of-day is ahead of (i.e., east of) or behind (i.e., west of) Universal Time. The first two digits indicate the number of hours difference from Universal Time, and the last two digits indicate the number of minutes difference from Universal Time. (Hence, +hhmm means +(hh * 60 + mm) minutes, and -hhmm means -(hh * 60 + mm) minutes). The form "+0000" SHOULD be used to indicate a time zone at Universal Time. Though "-0000" also indicates Universal Time, it is used to indicate that the time was generated on a system that may be in a local time zone other than Universal Time and therefore indicates that the date-time contains no information about the local time zone.

zone (帯) は date と time-of-date の協定世界時 (UTC; 以前はグリニッジ標準時として知られていました。訳注: 厳密には UTC と GMT は異なりますが、計算機分野ではあまり区別されません。) からの時差を指定します。 "+" と "-" は time-of-date が世界時の先 (つまり東) か後 (つまり西) かを示します。 最初の2桁は世界時との時の差の値を、後の2桁は世界時との分の差の値を示します。 (よって、 +hhmm は +(hh * 60 + mm) 分を表します。) "+0000" は世界時の時間帯を表すのに使用するのがよいです。 "-0000" も世界時を表しますが、世界時以外の地方時かもしれない処理系で時刻が生成されたことを示すのに使われるので、 date-time が地方時間帯についての情報を含んでいないことを示します。

A date-time specification MUST be semantically valid. That is, the day-of-the-week (if included) MUST be the day implied by the date, the numeric day-of-month MUST be between 1 and the number of days allowed for the specified month (in the specified year), the time-of-day MUST be in the range 00:00:00 through 23:59:60 (the number of seconds allowing for a leap second; see [STD12]), and the zone MUST be within the range -9959 through +9959.

date-time 記述は意味的に妥当なものでなければなりません。 これは、曜日は (含まれていれば) 日付の暗示する曜日でなければならず、 day-of-month の数値は1から (指定した年の) 指定した月であり得る日の数までの間でなければなりませんし、 time-of-day は範囲 00:00:00 〜 23:59:60 (閏秒で認められる秒の数。 STD12 参照。) の間になければなりませんし、 zone は範囲 -9959 〜 +9959 の中になければなりません。

RFC 2822 4.3. Obsolete Date and Time

The syntax for the obsolete date format allows a 2 digit year in the date field and allows for a list of alphabetic time zone specifications that were used in earlier versions of this standard. It also permits comments and folding white space between many of the tokens.

時代遅れの日付形式は日付欄中で2桁年号を認めており、またこの規格の早期の版で使われていたアルファベットの時間帯記述の表も認めています。また、多くの字句の間に注釈や折畳み空白間隔を許しています。

• obs-day-of-week = [CFWS] day-name [CFWS]
• obs-year = [CFWS] 2*DIGIT [CFWS]
• obs-month = CFWS month-name CFWS
• obs-day = [CFWS] 1*2DIGIT [CFWS]
• obs-hour = [CFWS] 2DIGIT [CFWS]
• obs-minute = [CFWS] 2DIGIT [CFWS]
• obs-second = [CFWS] 2DIGIT [CFWS]

obs-zone        =       "UT" / "GMT" /          ; Universal Time
                                                ; North American UT
                                                ; offsets

                        "EST" / "EDT" /         ; Eastern:  - 5/ - 4
                        "CST" / "CDT" /         ; Central:  - 6/ - 5
                        "MST" / "MDT" /         ; Mountain: - 7/ - 6
                        "PST" / "PDT" /         ; Pacific:  - 8/ - 7

                        %d65-73 /               ; Military zones - "A"
                        %d75-90 /               ; through "I" and "K"
                        %d97-105 /              ; through "Z", both
                        %d107-122               ; upper and lower case

Where a two or three digit year occurs in a date, the year is to be interpreted as follows: If a two digit year is encountered whose value is between 00 and 49, the year is interpreted by adding 2000, ending up with a value between 2000 and 2049. If a two digit year is encountered with a value between 50 and 99, or any three digit year is encountered, the year is interpreted by adding 1900.

日付中に2桁か3桁の数値が出てきたら、年は次のように解釈します。 2桁の数字が値 00 〜 49 の間で出てきた場合、年は 2000 を足して 2000 〜 2049 として解釈します。2桁の数字が値 50 〜 99 で出てきた場合、または3桁の数字の年が現れた場合は、年は 1900 を加えて解釈します。

In the obsolete time zone, "UT" and "GMT" are indications of "Universal Time" and "Greenwich Mean Time" respectively and are both semantically identical to "+0000".

時代遅れの時間帯 "UT" と "GMT" は「世界時」と「グリニッジ標準時」 をそれぞれ表し、共に意味的には "+0000" と同等です。

The remaining three character zones are the US time zones. The first letter, "E", "C", "M", or "P" stands for "Eastern", "Central", "Mountain" and "Pacific". The second letter is either "S" for "Standard" time, or "D" for "Daylight" (or summer) time. Their interpretations are as follows:

残りの3文字の帯は合衆国の時間帯です。最初の文字 "E", "C", "M", "P" は「東部」, 「中部」, 「山岳部」, 「太平洋」 を意味します。2文字目は「標準」時の "S" か、「夏」時間の "D" です。これらの解釈は次のようにします。

   EDT is semantically equivalent to -0400
   EST is semantically equivalent to -0500
   CDT is semantically equivalent to -0500
   CST is semantically equivalent to -0600
   MDT is semantically equivalent to -0600
   MST is semantically equivalent to -0700
   PDT is semantically equivalent to -0700
   PST is semantically equivalent to -0800

The 1 character military time zones were defined in a non-standard way in [RFC822] and are therefore unpredictable in their meaning. The original definitions of the military zones "A" through "I" are equivalent to "+0100" through "+0900" respectively; "K", "L", and "M" are equivalent to "+1000", "+1100", and "+1200" respectively; "N" through "Y" are equivalent to "-0100" through "-1200" respectively; and "Z" is equivalent to "+0000". However, because of the error in [RFC822], they SHOULD all be considered equivalent to "-0000" unless there is out-of-band information confirming their meaning.

1文字の軍の時間帯は RFC 822 で標準でない方法で定義されており、従ってその意味は予想出来ません。軍の帯の元の定義は "A" から "I" は "+0100" から "+0900" とそれぞれ等しく、 "K", "L", "M" は "+1000", "+1100", "+1200" とそれぞれ等しく、 "N" から "Y" はそれぞれ "-0100" から "-1200" とそれぞれ等しく、 "Z" は "+0000" と等しいというものでした。しかし RFC 822 の誤りのため、その意味を確認する外部情報がない限りこれらはすべて "-0000" と等しいとみなすのが良いです。

Other multi-character (usually between 3 and 5) alphabetic time zones have been used in Internet messages. Any such time zone whose meaning is not known SHOULD be considered equivalent to "-0000" unless there is out-of-band information confirming their meaning.

他の複数文字 (通常3〜5文字の間) のアルファベットの時間帯が Internet メッセージで使われてきました。こうした時間帯で意味を知らないものは、その意味を確認する外部情報がない限り "-0000" と等しいとみなすのが良いです。