When the receiver-SMTP accepts a message either for relaying
            or for final delivery it inserts at the beginning of the
            mail data a time stamp line.  The time stamp line indicates
            the identity of the host that sent the message, and the
            identity of the host that received the message (and is
            inserting this time stamp), and the date and time the
            message was received.  Relayed messages will have multiple
            time stamp lines.

            Example of Return Path and Received Time Stamps

      Return-Path: <@GHI.ARPA,@DEF.ARPA,@ABC.ARPA:JOE@ABC.ARPA>   
      Received: from GHI.ARPA by JKL.ARPA ; 27 Oct 81 15:27:39 PST
      Received: from DEF.ARPA by GHI.ARPA ; 27 Oct 81 15:15:13 PST
      Received: from ABC.ARPA by DEF.ARPA ; 27 Oct 81 15:01:59 PST
      Date: 27 Oct 81 15:01:01 PST                                
      From: JOE@ABC.ARPA                                          
      Subject: Improved Mailing System Installed                  
      To: SAM@JKL.ARPA                                            
                                    
      This is to inform you that ...                              

                               Example 8

         The time stamp line and the return path line are formally
         defined as follows:

         <return-path-line> ::= "Return-Path:" <SP><reverse-path><CRLF>

         <time-stamp-line> ::= "Received:" <SP> <stamp> <CRLF>

            <stamp> ::= <from-domain> <by-domain> <opt-info> ";"
                      <daytime>

            <from-domain> ::= "FROM" <SP> <domain> <SP>

            <by-domain> ::= "BY" <SP> <domain> <SP>

            <opt-info> ::= [<via>] [<with>] [<id>] [<for>]

            <via> ::= "VIA" <SP> <link> <SP>

            <with> ::= "WITH" <SP> <protocol> <SP>

            <id> ::= "ID" <SP> <string> <SP>

            <for> ::= "FOR" <SP> <path> <SP>

            <link> ::= The standard names for links are registered with
                      the Network Information Center.

            <protocol> ::= The standard names for protocols are
                      registered with the Network Information Center.

            <daytime> ::= <SP> <date> <SP> <time>

            <date> ::= <dd> <SP> <mon> <SP> <yy>

            <time> ::= <hh> ":" <mm> ":" <ss> <SP> <zone>

            <dd> ::= the one or two decimal integer day of the month in
                      the range 1 to 31.

            <mon> ::= "JAN" | "FEB" | "MAR" | "APR" | "MAY" | "JUN" |
                      "JUL" | "AUG" | "SEP" | "OCT" | "NOV" | "DEC"

            <yy> ::= the two decimal integer year of the century in the
                      range 00 to 99.

            <hh> ::= the two decimal integer hour of the day in the
                      range 00 to 24.

            <mm> ::= the two decimal integer minute of the hour in the
                      range 00 to 59.

            <ss> ::= the two decimal integer second of the minute in the
                      range 00 to 59.

            <zone> ::= "UT" for Universal Time (the default) or other
                      time zone designator (as in [2]).

                        Time Stamp Line Example

      Received: FROM ABC.ARPA BY XYZ.ARPA ; 22 OCT 81 09:23:59 PDT

         Received: from ABC.ARPA by XYZ.ARPA via TELENET with X25
                   id M12345 for Smith@PDQ.ARPA ; 22 OCT 81 09:23:59 PDT

                               Example 10

     received    =  "Received"    ":"            ; one per relay
                       ["from" domain]           ; sending host
                       ["by"   domain]           ; receiving host
                       ["via"  atom]             ; physical path
                      *("with" atom)             ; link/mail protocol
                       ["id"   msg-id]           ; receiver msg id
                       ["for"  addr-spec]        ; initial form
                        ";"    date-time         ; time received

        A copy of this field is added by each transport  service  that
        relays the message.  The information in the field can be quite
        useful for tracing transport problems.

        The names of the sending  and  receiving  hosts  and  time-of-
        receipt may be specified.  The "via" parameter may be used, to
        indicate what physical mechanism the message  was  sent  over,
        such  as  Arpanet or Phonenet, and the "with" parameter may be
        used to indicate the mail-,  or  connection-,  level  protocol
        that  was  used, such as the SMTP mail protocol, or X.25 tran-
        sport protocol.

        Note:  Several "with" parameters may  be  included,  to  fully
               specify the set of protocols that were used.

        Some transport services queue mail; the internal message iden-
        tifier that is assigned to the message may be noted, using the
        "id" parameter.  When the  sending  host  uses  a  destination
        address specification that the receiving host reinterprets, by
        expansion or transformation, the receiving host  may  wish  to
        record  the original specification, using the "for" parameter.
        For example, when a copy of mail is sent to the  member  of  a
        distribution  list,  this  parameter may be used to record the
        original address that was used to specify the list.

When an SMTP server receives a message for delivery or further processing, it MUST insert trace ("time stamp" or "Received") information at the beginning of the message content, as discussed in section 4.1.1.4.

SMTP サーバーがメッセイジを配送あるいは更なる処理のために 受け取った時には、跡 (「時間印」あるいは「受信した」) 情報を メッセイジ内容のはじめに、第4.1.1.4節で説明したように 挿入しなければなりません。

This line MUST be structured as follows:

この行は次のように構成しなければなりません。

• The FROM field, which MUST be supplied in an SMTP environment, SHOULD contain both (1) the name of the source host as presented in the EHLO command and (2) an address literal containing the IP address of the source, determined from the TCP connection.
• FROM 領域。これは SMTP 環境ではつけなければならず、(1) EHLO 命令で知らされた原ホストの名前 (2) 原ホストの IP アドレスを含むアドレス・リテラルの両者を含めるべきです。
• The ID field MAY contain an "@" as suggested in RFC 822, but this is not required.
• ID 領域は RFC 822 で提案されているように「@」から成っていてもよいですが、惟は必要ではありません。
• The FOR field MAY contain a list of <path> entries when multiple RCPT commands have been given. This may raise some security issues and is usually not desirable; see section 7.2.
• FOR 領域は複数の RCPT 命令が与えられている時に <path> 項目の表から成っていてもよいです。これは保安問題を起こしかねないし通常望ましくありません。第7.2節を参照。

An Internet mail program MUST NOT change a Received: line that was previously added to the message header. SMTP servers MUST prepend Received lines to messages; they MUST NOT change the order of existing lines or insert Received lines in any other location.

Internet メイル・プログラムは前にメッセイジ・ヘッダーに追加された Received: 行 を変更してはいけません。 SMTP サーバーは Received 行を メッセイジのはじめに加えなければなりません。 既存の行の順番を変えたり Received 行を他の場所に入れたりしてはいけません。

As the Internet grows, comparability of Received fields is important for detecting problems, especially slow relays. SMTP servers that create Received fields SHOULD use explicit offsets in the dates (e.g., -0800), rather than time zone names of any type. Local time (with an offset) is preferred to UT when feasible. This formulation allows slightly more information about local circumstances to be specified. If UT is needed, the receiver need merely do some simple arithmetic to convert the values. Use of UT loses information about the time zone-location of the server. If it is desired to supply a time zone name, it SHOULD be included in a comment.

Internet の成長に従って、 Received 領域の比較は問題、特に 配送遅延の特定に重要となりました。 Received 領域を作る SMTP サーバーは いかなる種の時間帯名よりも日付の明示的な差 (例えば -0800) を使うべきです。 (差つき)現地時間は UT (協定世界時) より利用価値があります。 この方法なら指定される地域事情について幾分多くの情報を伝えられます。 UT が必要なら、受信者が単に値を直す計算をすればいいだけです。 UT を使うとサーバーの時間帯位置についての情報が失われます。 時間帯名を示すことが必要なら、注釈に入れるべきです。

(中(Return-Path:関連)略)

The time stamp line and the return path line are formally defined as follows:

時間印行及び復帰経路行は正式には次のように定義します。

  Return-path-line = "Return-Path:" FWS Reverse-path <CRLF>

  Time-stamp-line = "Received:" FWS Stamp <CRLF>

  Stamp = From-domain By-domain Opt-info ";"  FWS date-time

      ; where "date-time" is as defined in [32]
      ; but the "obs-" forms, especially two-digit
      ; years, are prohibited in SMTP and MUST NOT be used.

; 「date-time」はRFC2822の日付形式で定義されたものですが、 「obs-」形式、特に2桁年は SMTP では禁止し、使用してはなりません。

  From-domain = "FROM" FWS Extended-Domain CFWS

  By-domain = "BY" FWS Extended-Domain CFWS

  Extended-Domain = Domain /
           ( Domain FWS "(" TCP-info ")" ) /
           ( Address-literal FWS "(" TCP-info ")" )

  TCP-info = Address-literal / ( Domain FWS Address-literal )
      ; Information derived by server from TCP connection
      ; not client EHLO.

; サーバーが、クライアントの EHLO ではなく TCP 接続から得た情報

  Opt-info = [Via] [With] [ID] [For]

  Via = "VIA" FWS Link CFWS

  With = "WITH" FWS Protocol CFWS

  ID = "ID" FWS String / msg-id CFWS

  For = "FOR" FWS 1*( Path / Mailbox ) CFWS

  Link = "TCP" / Addtl-Link
  Addtl-Link = Atom
      ; Additional standard names for links are registered with the
         ; Internet Assigned Numbers Authority (IANA).  "Via" is
         ; primarily of value with non-Internet transports.  SMTP
         ; servers SHOULD NOT use unregistered names.

; 追加のリンクの標準名称は Internet 登録番号事務局 (IANA) で登録 されます。「Via」は主として非 Internet 配送路の値です。 SMTP サーバーは非登録名を使用すべきでありません。

訳注: 2002年3月現在、「UUCP」が登録されています。

  Protocol = "ESMTP" / "SMTP" / Attdl-Protocol
  Attdl-Protocol = Atom
      ; Additional standard names for protocols are registered with the
         ; Internet Assigned Numbers Authority (IANA).  SMTP servers
         ; SHOULD NOT use unregistered names.

; 追加のプロトコルの標準名は Internet 登録番号事務局 (IANA) で登録 されます。 SMTP サーバーは非登録名を使用すべきでありません。

訳注: 2002年3月現在、追加の登録はありません。

      address-literal = "[" IPv4-address-literal /
                            IPv6-address-literal /
                            General-address-literal "]"
            ; See section 4.1.3

      Atom = 1*atext

      String = Atom / Quoted-string

      IPv4-address-literal = Snum 3("." Snum)
      IPv6-address-literal = "IPv6:" IPv6-addr
      General-address-literal = Standardized-tag ":" 1*dcontent
      Standardized-tag = Ldh-str
            ; MUST be specified in a standards-track RFC
            ; and registered with IANA

      Snum = 1*3DIGIT  ; representing a decimal integer
            ; value in the range 0 through 255
      Let-dig = ALPHA / DIGIT
      Ldh-str = *( ALPHA / DIGIT / "-" ) Let-dig

      IPv6-addr = IPv6-full / IPv6-comp / IPv6v4-full / IPv6v4-comp
      IPv6-hex  = 1*4HEXDIG
      IPv6-full = IPv6-hex 7(":" IPv6-hex)
      IPv6-comp = [IPv6-hex *5(":" IPv6-hex)] "::" [IPv6-hex *5(":"
                 IPv6-hex)]
            ; The "::" represents at least 2 16-bit groups of zeros
            ; No more than 6 groups in addition to the "::" may be
            ; present
      IPv6v4-full = IPv6-hex 5(":" IPv6-hex) ":" IPv4-address-literal
      IPv6v4-comp = [IPv6-hex *3(":" IPv6-hex)] "::"
                   [IPv6-hex *3(":" IPv6-hex) ":"] IPv4-address-literal
            ; The "::" represents at least 2 16-bit groups of zeros
            ; No more than 4 groups in addition to the "::" and
            ; IPv4-address-literal may be present

      Path = "<" [ A-d-l ":" ] Mailbox ">"
      Mailbox = Local-part "@" Domain

The trace fields are a group of header fields consisting of an optional "Return-Path:" field, and one or more "Received:" fields. The "Return-Path:" header field contains a pair of angle brackets that enclose an optional addr-spec. The "Received:" field contains a (possibly empty) list of name/value pairs followed by a semicolon and a date-time specification. The first item of the name/value pair is defined by item-name, and the second item is either an addr-spec, an atom, a domain, or a msg-id. Further restrictions may be applied to the syntax of the trace fields by standards that provide for their use, such as [RFC2821].

追跡欄は省略可能な "Return-Path:" 欄と1つ以上の "Received:" 欄からなる頭欄の集団です。 "Return-Path:" 頭欄は angle 括弧の組とそれに囲まれた省略可能な addr-spec で構成されます。 "Received:" 欄は (空かも知れない) 名前/値の組の表にセミコロンと date-time 記述が続くものです。名前/値組の最初の項目は item-name で定義され、2番目の項目は addr-spec, atom, domain, または msg-id で定義されます。追跡欄の構文はこれを使う RFC 2821 のような規格により更なる制限が加えられるかもしれません。

• trace = [return] 1*received
• return = "Return-Path:" path CRLF
• path = ([CFWS] "<" ([CFWS] / addr-spec) ">" [CFWS]) / obs-path
• received = "Received:" name-val-list ";" date-time CRLF
• name-val-list = [CFWS] [name-val-pair *(CFWS name-val-pair)]
• name-val-pair = item-name CFWS item-value
• item-name = ALPHA *(["-"] (ALPHA / DIGIT))
• item-value = addr-spec / atom / domain / msg-id

A full discussion of the Internet mail use of trace fields is contained in [RFC2821]. For the purposes of this standard, the trace fields are strictly informational, and any formal interpretation of them is outside of the scope of this document.

追跡欄の Internet メイルでの仕様についての完全な議論は RFC 2821 に含まれています。この規格の目的では、追跡情報は完全に情報提供的なもので、これらの正式な解釈はこの文書の適用範囲外とします。

The obs-return and obs-received are again given here as template definitions, just as return and received are in section 3. Their full syntax is given in [RFC2821].

• obs-return = "Return-Path" *WSP ":" path CRLF
• obs-received = "Received" *WSP ":" name-val-list CRLF
• obs-path = obs-route-addr

Trace information should be added to the document with a convert

clause: "rfc822-to-8bit", "rfc822-to-base-64" or "rfc822-to-quoted-

printable" e.g.,

Received: from dbc.mtview.ca.us by dbc.mtview.ca.us

convert rfc822-to-8bit; Tue, 01 Sep 1992 01:18:00 -0700

Received: from dial-3-236.emitel.hu(194.149.57.236) by brutus via csmap (V6.0)

id srcAAAb2aGGy; Tue, 6 Apr 04 17:55:45 +0200

Received: from x ([x.x.60.10]) by x.net with MailEnab

le ESMTP; Sun, 28 Dec 2014 11:30:16 +0200